Visual Basic Source Code/Visual Basic Source Code.iso/vbsource/dayquote/dayquote.bas

BASIC Source File | 1995-05-09 | 29.4 KB | 834 lines

    DefInt A-Z

    CONST FALSE = 0
    CONST TRUE = 1

    DECLARE SUB DoQuote (FileName$)
    DECLARE SUB ParseCommandLine (Num%, Arg$())
    DECLARE SUB PutQuote (Text$)
    DECLARE SUB PrintDoc (FileName$)
    DECLARE SUB ShowGimme ()
    DECLARE SUB ShowHelp ()
    DECLARE SUB ShowSyntax ()

    DIM ErrorString$(76): FOR j = 1 TO 76: READ ErrorString$(j): NEXT
    Dim Arguments$(1 To 20)
    Dim Shared QuoteText$(1 To 22)
    Dim Shared ForeColor, BackColor, Justification
    Dim Shared StartCol, EndCol, TopLine, WipeScreen

    PRINT

    CALL ParseCommandLine(NumArgs%, Arguments$())

    IF Arguments$(1) = "" THEN ShowSyntax

    FOR i = 1 TO NumArgs%
        SELECT CASE LEFT$(Arguments$(i), 2)
        CASE "/?"
            ShowHelp
        CASE "/F"
            IF MID$(Arguments$(i), 3, 1) = ":" THEN
                ExpectedArg$ = MID$(Arguments$(i), 4, LEN(Arguments$(i)))
                SELECT CASE ExpectedArg$
                CASE "BLACK", "BLK"
                    ForeColor% = 1
                CASE "BLUE", "BLU"
                    ForeColor% = 2
                CASE "GREEN", "GRN"
                    ForeColor% = 3
                CASE "CYAN", "CYA"
                    ForeColor% = 4
                CASE "RED"
                    ForeColor% = 5
                CASE "MAGENTA", "MAG"
                    ForeColor% = 6
                CASE "BROWN", "BRN"
                    ForeColor% = 7
                CASE "WHITE", "WHT"
                    ForeColor% = 8
                CASE "GRAY", "GREY", "GRY"
                    ForeColor% = 9
                CASE "LTBLUE", "LBL"
                    ForeColor% = 10
                CASE "LTGREEN", "LGR"
                    ForeColor% = 11
                CASE "LTCYAN", "LCY"
                    ForeColor% = 12
                CASE "LTRED", "LRD"
                    ForeColor% = 13
                CASE "LTMAGENTA", "LMG"
                    ForeColor% = 14
                CASE "YELLOW", "YEL"
                    ForeColor% = 15
                CASE "BRWHITE", "BRW"
                    ForeColor% = 16
                CASE ELSE
                    CommandError = TRUE
                    PRINT "Invalid foreground specification:  "; ExpectedArg$
                END SELECT
                ExpectedArg$ = ""
            ELSE
                CommandError = TRUE
                PRINT "Missing colon in switch:  "; Arguments$(i)
            END IF
        CASE "/B"
            IF MID$(Arguments$(i), 3, 1) = ":" THEN
                ExpectedArg$ = MID$(Arguments$(i), 4, LEN(Arguments$(i)))
                SELECT CASE ExpectedArg$
                CASE "BLACK", "BLK"
                    BackColor% = 1
                CASE "BLUE", "BLU"
                    BackColor% = 2
                CASE "GREEN", "GRN"
                    BackColor% = 3
                CASE "CYAN", "CYA"
                    BackColor% = 4
                CASE "RED"
                    BackColor% = 5
                CASE "MAGENTA", "MAG"
                    BackColor% = 6
                CASE "BROWN", "BRN"
                    BackColor% = 7
                CASE "WHITE", "WHT"
                    BackColor% = 8
                CASE "GRAY", "GREY", "GRY"
                    BackColor% = 9
                CASE "LTBLUE", "LBL"
                    BackColor% = 10
                CASE "LTGREEN", "LGR"
                    BackColor% = 11
                CASE "LTCYAN", "LCY"
                    BackColor% = 12
                CASE "LTRED", "LRD"
                    BackColor% = 13
                CASE "LTMAGENTA", "LMG"
                    BackColor% = 14
                CASE "YELLOW", "YEL"
                    BackColor% = 15
                CASE "BRWHITE", "BRW"
                    BackColor% = 16
                CASE ELSE
                    CommandError = TRUE
                    PRINT "Invalid background specification:  "; ExpectedArg$
                END SELECT
                ExpectedArg$ = ""
            ELSE
                CommandError = TRUE
                PRINT "Missing colon in switch:  "; Arguments$(i)
            END IF
        CASE "/L"
            IF LEN(Arguments$(i)) = 2 THEN
                IF NOT (Justification) THEN
                    Justification = 1
                ELSE
                    CommandError = TRUE
                    PRINT "Multiple text justifications are not allowed:  "; Arguments$(i)
                END IF
            ELSE
                CommandError = TRUE
                PRINT "Invalid switch:  "; Arguments$(i)
            END IF
        CASE "/C"
            IF LEN(Arguments$(i)) = 2 THEN
                IF NOT (Justification) THEN
                    Justification = 2
                ELSE
                    CommandError = TRUE
                    PRINT "Multiple text justifications are not allowed:  "; Arguments$(i)
                END IF
            ELSE
                CommandError = TRUE
                PRINT "Invalid switch:  "; Arguments$(i)
            END IF
        CASE "/R"
            IF LEN(Arguments$(i)) = 2 THEN
                IF NOT (Justification) THEN
                    Justification = 3
                ELSE
                    CommandError = TRUE
                    PRINT "Multiple text justifications are not allowed:  "; Arguments$(i)
                END IF
            ELSE
                CommandError = TRUE
                PRINT "Invalid switch:  "; Arguments$(i)
            END IF
        CASE "/S"
            IF MID$(Arguments$(i), 3, 1) = ":" THEN
                ExpectedArg = VAL(MID$(Arguments$(i), 4, LEN(Arguments$(i))))
                IF (ExpectedArg > 0) AND (ExpectedArg < 31) THEN
                    StartCol = ExpectedArg
                ELSE
                    CommandError = TRUE
                    PRINT "Invalid starting column:  "; MID$(Arguments$(i), 4, LEN(Arguments$(i)))
                END IF
                ExpectedArg = 0
            ELSE
                CommandError = TRUE
                PRINT "Missing colon in switch:  "; Arguments$(i)
            END IF
        CASE "/E"
            IF MID$(Arguments$(i), 3, 1) = ":" THEN
                ExpectedArg = VAL(MID$(Arguments$(i), 4, LEN(Arguments$(i))))
                IF (ExpectedArg > 49) AND (ExpectedArg < 81) THEN
                    EndCol = ExpectedArg
                ELSE
                    CommandError = TRUE
                    PRINT "Invalid ending column:  "; MID$(Arguments$(i), 4, LEN(Arguments$(i)))
                END IF
                ExpectedArg = 0
            ELSE
                CommandError = TRUE
                PRINT "Missing colon in switch:  "; Arguments$(i)
            END IF
        CASE "/T"
            IF MID$(Arguments$(i), 3, 1) = ":" THEN
                ExpectedArg = VAL(MID$(Arguments$(i), 4, LEN(Arguments$(i))))
                IF (ExpectedArg > 0) AND (ExpectedArg < 25) THEN
                    TopLine = ExpectedArg
                ELSE
                    CommandError = TRUE
                    PRINT "Invalid top line:  "; MID$(Arguments$(i), 4, LEN(Arguments$(i)))
                END IF
                ExpectedArg = 0
            ELSE
                CommandError = TRUE
                PRINT "Missing colon in switch:  "; Arguments$(i)
            END IF
        CASE "/W"
            IF LEN(Arguments$(i)) = 2 THEN
                WipeScreen = TRUE
            ELSE
                CommandError = TRUE
                PRINT "Invalid switch:  "; Arguments$(i)
            END IF
        CASE "/$"
            IF CommandError = FALSE THEN
                IF LEN(Arguments$(i)) = 2 THEN
                    ShowGimme
                ELSE
                    CommandError = TRUE
                    PRINT "Invalid switch:  "; Arguments$(i)
                END IF
            END IF
        CASE "/D"
            ON ERROR GOTO PrintDocError
            IF CommandError = FALSE THEN
                IF MID$(Arguments$(i), 3, 1) = ":" THEN
                    FileName$ = MID$(Arguments$(i), 4, LEN(Arguments$(i)))
                    IF FileName$ <> "" THEN
                        IF FileName$ <> "CLOCK$" THEN
                            FileName$ = MID$(Arguments$(i), 4, LEN(Arguments$(i)))
                        ELSE
                            ERROR 25
                        END IF
                        CALL PrintDoc(FileName$)
                    ELSE
                        FileName$ = "DAYQUOTE.DOC"
                        CALL PrintDoc(FileName$)
                    END IF
                ELSE
                    FileName$ = "DAYQUOTE.DOC"
                    CALL PrintDoc(FileName$)
                END IF
            END IF
        CASE ELSE
            IF LEFT$(Arguments$(i), 1) = "/" THEN
                CommandError = TRUE
                PRINT "Invalid switch:  "; Arguments$(i)
            ELSE
                QuoteFile$ = Arguments$(i)
            END IF
        END SELECT
    NEXT i

    IF QuoteFile$ = "" THEN
        PRINT "Quote file not specified."
        PRINT
        PRINT "Type 'DAYQUOTE /?' for help."
    ELSE
        IF (CommandError) THEN
            PRINT
            PRINT "Type 'DAYQUOTE /?' for help."
        ELSE
            SELECT CASE QuoteFile$
            CASE "CON", "AUX", "PRN", "CLOCK$", "COM1", "COM2"
                PRINT "Quote file can not be a reserved device name:  "; QuoteFile$
            CASE "COM3", "COM4", "LPT1", "LPT2", "LPT3"
                PRINT "Quote file can not be a reserved device name:  "; QuoteFile$
            CASE ELSE
                CALL DoQuote(QuoteFile$)
            END SELECT
        END IF
    END IF

    SYSTEM


QuoteFileError:
    SELECT CASE ERR
    CASE 6
        PRINT "Overflow reading file:  "; QuoteFile$
        PRINT QuoteFile$; " is too large."
        SYSTEM
    CASE 53
        PRINT "Problem looking for quote file:  "; QuoteFile$
        SYSTEM
    CASE 57
        PRINT "Unsupported disk format encountered looking for file:  "; QuoteFile$
        SYSTEM
    CASE 64
        PRINT "Bad file name:  "; QuoteFile$
        SYSTEM
    CASE 71
        PRINT "Drive not ready looking for quote file:  "; QuoteFile$
        SYSTEM
    CASE 76
        PRINT "Path not found looking for quote file:  "; QuoteFile$
        SYSTEM
    CASE ELSE
        PRINT "System error number #"; LTRIM$(STR$(ERR)); " handling quote file:  "; QuoteFile$
        PRINT "- "; ErrorString$(ERR); " -"
        SYSTEM
    END SELECT

PrintDocError:
    SELECT CASE ERR
    CASE 25
        SELECT CASE FileName$
        CASE "CLOCK$"
            PRINT "Are you really that determined to fuck things up?"
        CASE "PRN"
            PRINT "Printer is not responding at attempt to print file."
        CASE "COM1", "COM2", "COM3", "COM4", "LPT1", "LPT2", "LPT3"
            PRINT FileName$; " is not responding at attempt to print file."
        CASE ELSE
            PRINT "Device fault error printing to file:  "; FileName$
        END SELECT
        SYSTEM
    CASE 57
        PRINT "Unsupported disk format encountered printing to file:  "; FileName$
        SYSTEM
    CASE 64
        PRINT "Bad file name:  "; FileName$
        SYSTEM
    CASE 68
        PRINT "Path not found printing to file:  "; FileName$
        SYSTEM
    CASE 71
        PRINT "Drive not ready printing to file:  "; FileName$
        SYSTEM
    CASE 75
        SELECT CASE TryDirectory
        CASE FALSE
            TryDirectory = TRUE
            SELECT CASE RIGHT$(FileName$, 1)
            CASE ":", "\"
                FileName$ = FileName$ + "DAYQUOTE.DOC"
            CASE ELSE
                FileName$ = FileName$ + "\DAYQUOTE.DOC"
            END SELECT
            RESUME
        CASE ELSE
            PRINT "Path not found printing to file:  "; FileName$
            SYSTEM
        END SELECT
    CASE 76
        PRINT "Path not found printing to file:  "; FileName$
        SYSTEM
    CASE ELSE
        IF ERR = 61 THEN KILL FileName$: PRINT
        PRINT "System error number #"; LTRIM$(STR$(ERR)); " printing to file:  "; FileName$
        PRINT "- "; ErrorString$(ERR); " -"
        SYSTEM
    END SELECT

MiscErrors:
    SELECT CASE ERR
    CASE ELSE
        PRINT "System error number #"; LTRIM$(STR$(ERR)); " displaying quote from file:  "; QuoteFile$
        PRINT "- "; ErrorString$(ERR); " -"
        SYSTEM
    END SELECT


'════════════════════════════════════════════════════════════════════════════
'   BASIC ERRor string data
'════════════════════════════════════════════════════════════════════════════
    DATA "NEXT without FOR"
    DATA "Syntax error"
    DATA "RETURN without GOSUB"
    DATA "Out of DATA"
    DATA "Illegal function call"
    DATA "Overflow"
    DATA "Out of memory"
    DATA "Undefined line number"
    DATA "Subscript out of range"
    DATA "Duplicate definition"
    DATA "Division by zero"
    DATA "Illegal direct"
    DATA "Type mismatch"
    DATA "Out of string space"
    DATA "String too long"
    DATA "String formula too complex"
    DATA "Can't continue"
    DATA "Undefined user function"
    DATA "No RESUME"
    DATA "RESUME without error"
    DATA "Description not found"
    DATA "Missing operand"
    DATA "Line buffer overflow"
    DATA "Device timeout"
    DATA "Device fault"
    DATA "FOR without NEXT"
    DATA "Out of paper"
    DATA "Description not found"
    DATA "WHILE without WEND"
    DATA "WEND without WHILE"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Description not found"
    DATA "FIELD overflow"
    DATA "Internal error"
    DATA "Bad file number"
    DATA "File not found"
    DATA "Bad file mode"
    DATA "File already open"
    DATA "Description not found"
    DATA "Device I/O error"
    DATA "File already exists"
    DATA "Description not found"
    DATA "Description not found"
    DATA "Disk full"
    DATA "Input past end"
    DATA "Bad record number"
    DATA "Bad file name"
    DATA "Description not found"
    DATA "Direct statement in file"
    DATA "Too many files"
    DATA "Device unavailable"
    DATA "Communication buffer overflow"
    DATA "Disk write-protected - Permission denied"
    DATA "Disk not ready"
    DATA "Disk media error"
    DATA "Advanced feature"
    DATA "Rename across disks"
    DATA "Path/file access error"
    DATA "Path not found"

Sub DoQuote (QuoteFile$)

    On Error GoTo QuoteFileError

    Open QuoteFile$ For Input As #1
    Close #1

    Open QuoteFile$ For Binary As #1

    If LOF(1) = 0 Then
        Print "Attempt to read an empty file:  "; QuoteFile$
        Close #1
        Exit Sub
    End If

    Randomize Timer
    Position! = Fix(Rnd * LOF(1)) + 2

    Do While BeginningFound = False
        Get #1, Position!, Dummy%
        Char$ = Left$(MKI$(Dummy%), 1)

        Select Case Char$
        Case Chr$(13), Chr$(10)
            Count = Count + 1
            If Count = 4 Then
                If BeginningReady = True Then
                    If (Fix(Rnd * 10) + 1) > 3 Then
                        BeginningFound = True
                    Else
                        BeginningReady = False
                        Count = 0
                    End If
                End If
            End If
        Case Chr$(32), Chr$(9)
            Count = 0
        Case Chr$(0) To Chr$(8), Chr$(11), Chr$(12), Chr$(26), Chr$(29), Chr$(30)
            Print "Attempt to read a binary file or non-text characters found in:  "; QuoteFile$
            If Position! < 100 Then
                Position! = Position! + (100 - Position!)
            Else
                Position! = Position! - 100
            End If
            BreakPos! = Position!
            StartPos! = Position!
            Print
            Print "Reference block:"
            Print String$(80, "─");
            Do While Done = False
                If (Position! = LOF(1)) Then Done = True
                If (Position! = BreakPos! + 200) Then Done = True
                Get #1, Position!, Dummy%
                Char$ = Left$(MKI$(Dummy%), 1)
                Select Case Char$
                Case Chr$(10)
                    If Last$ <> Chr$(13) Then
                        Print Char$;
                    End If
                Case Chr$(7), Chr$(11), Chr$(12), Chr$(29), Chr$(30)
                Case Else
                    Print Char$;
                End Select
                Position! = Position! + 1
                Last$ = Char$
            Loop
            Print String$(80, "─")
            Print "found at location"; StartPos!; "to"; Position!
            Close #1
            Exit Sub
        Case Else
            BegPos! = Position!
            BeginningReady = True
            Count = 0
        End Select

        Size% = Size% + 1
        If Size% > 1672 Then
            Print "File read error - size of object in:  "; QuoteFile$
            Print QuoteFile$; " is possibly not a quote file."
            Close #1
            Exit Sub
        End If

        Position! = Position! - 1
        If Position! = 0 Then
            If BeginningReady = True Then
                BeginningFound = True
            Else
                Position! = LOF(1)
            End If
        End If
    Loop

    Count = 0
    Size% = 0
    Position! = BegPos!

    Do While EndingFound = False
        If Position! = LOF(1) Then EndingFound = True
        Get #1, Position!, Dummy%
        Char$ = Left$(MKI$(Dummy%), 1)

        Select Case Char$
        Case Chr$(13), Chr$(10)
            If Int(Count / 2) = Count / 2 Then Quote$ = Quote$ + Chr$(32)
            Last$ = Chr$(32)
            Count = Count + 1
            If EndingReady = True Then
                Count = 0
                EndingFound = True
            End If
            If Count = 2 Then
                EndingReady = True
            End If
            If Position! = LOF(1) Then
                Count = 0
                EndingFound = True
            End If
        Case Chr$(32), Chr$(9)
            If Last$ <> Char$ Then Quote$ = Quote$ + Char$
            Count = 0
        Case Chr$(0) To Chr$(8), Chr$(11), Chr$(12), Chr$(26), Chr$(29), Chr$(30)
            Print "Attempt to read a binary file or non-text characters found in:  "; QuoteFile$
            If Position! < 100 Then
                Position! = Position! + (100 - Position!)
            Else
                Position! = Position! - 100
            End If
            BreakPos! = Position!
            StartPos! = Position!
            Print
            Print "Reference block:"
            Print String$(80, "─");
            Do While Done = False
                If (Position! = LOF(1)) Then Done = True
                If (Position! = BreakPos! + 200) Then Done = True
                Get #1, Position!, Dummy%
                Char$ = Left$(MKI$(Dummy%), 1)
                Select Case Char$
                Case Chr$(10)
                    If Prev$ <> Chr$(13) Then
                        Print Char$;
                    End If
                Case Chr$(7), Chr$(11), Chr$(12), Chr$(29), Chr$(30)
                Case Else
                    Print Char$;
                End Select
                Position! = Position! + 1
                Prev$ = Char$
            Loop
            Print String$(80, "─")
            Print "found at location"; StartPos!; "to"; Position!
            Close #1
            Exit Sub
        Case Else
            Quote$ = Quote$ + Char$
            If EndingReady = True Then EndingReady = False
            Count = 0
        End Select

        Size% = Size% + 1
        If Size% > 1672 Then
            Print "File read error - size of object in:  "; QuoteFile$
            Print "  "; QuoteFile$; " is possibly not a quote file."
            Close #1
            Exit Sub
        End If

        Position! = Position! + 1
        Last$ = Char$
    Loop
    Count = 0

    Close #1

    If Quote$ <> "" Then
        Quote$ = LTrim$(RTrim$(Quote$)) + Chr$(32)
        Call PutQuote(Quote$)
    Else
        Print "No quotes found in file:  ", QuoteFile$
        Exit Sub
    End If

End Sub

Sub ParseCommandLine (NumArgs%, Args$())

    NumArgs% = 0: in = FALSE: switch = FALSE
    Comline$ = Command$
    Length = Len(Comline$)
    For Increment = 1 To Length
        Char$ = Mid$(Comline$, Increment, 1)
        Select Case Char$
        Case Chr$(32), Chr$(9)
            If (in) Then
                If NumArgs% = 20 Then Exit For
                NumArgs% = NumArgs% + 1
                in = False
            End If
        Case "/"
            If (in) Or (NumArgs% = 0) Then NumArgs% = NumArgs% + 1
            in = True
            Args$(NumArgs%) = Args$(NumArgs%) + Char$
        Case Else
            If (NumArgs% = 0) Then NumArgs% = NumArgs% + 1
            in = True
            Args$(NumArgs%) = Args$(NumArgs%) + Char$
        End Select
    Next Increment

    If NumArgs% > 0 Then If Args$(NumArgs%) = "" Then NumArgs% = NumArgs% - 1

End Sub

Sub PutQuote (Text$)

    On Error GoTo MiscErrors

    CurrentLine = CSRLIN

    If StartCol = 0 Then StartCol = 10
    If EndCol = 0 Then EndCol = 70
    If TopLine = 0 Then TopLine = CurrentLine

    QuoteWidth = EndCol - StartCol + 1 - 4
    StringLength = Len(Text$) - 1           ' -1 nullifies terminating char

    If StringLength > QuoteWidth Then
        If (StringLength / QuoteWidth) = Int(StringLength / QuoteWidth) Then
            NumLines = StringLength / QuoteWidth
        Else
            NumLines = Int(StringLength / QuoteWidth) + 1
        End If
    Else
        NumLines = 1
    End If

    If NumLines > 21 Then
        Print "Quote text is too long to fit in the specified frame."
        Exit Sub
    End If

    If InStr(Text$, "~~") Then
        MarkPos = InStr(Text$, "~~")
        AttribName$ = "- " + Left$(RTrim$(Mid$(Text$, MarkPos + 2, StringLength - MarkPos + 2)), QuoteWidth)
        AttribText$ = Space$(QuoteWidth - Len(AttribName$)) + AttribName$
        Text$ = RTrim$(Left$(Text$, MarkPos - 1)) + Chr$(32)
        Attribute = True
    End If

Compensate:

    For j = 1 To NumLines
        Portion$ = Mid$(Text$, LastRef + 1, QuoteWidth + 1)
        For k = Len(Portion$) To 1 Step -1
            If Mid$(Portion$, k, 1) = Chr$(32) Then
                QuoteText$(j) = LTrim$(RTrim$(Mid$(Portion$, 1, k - 1)))
                LastRef = LastRef + k
                Exit For
            ElseIf k = 1 Then
                QuoteText$(j) = Mid$(Portion$, 1, Len(Portion$) - 2) + "-"
                LastRef = LastRef + Len(Portion$) - 2
                Exit For
            Else
                QuoteText$(j) = LTrim$(RTrim$(Mid$(Portion$, 1, k)))
            End If
        Next k

        If j = NumLines Then
            If Right$(QuoteText$(j), 1) <> Mid$(Text$, StringLength, 1) Then
                LastRef = 0
                NumLines = NumLines + 1
                If NumLines > 21 Then
                    Print "Quote text is too long to fit in the specified frame."
                    Exit Sub
                End If
                GoTo Compensate
            End If
        End If

    Next j

    If Attribute = True Then QuoteText$(j - 1) = AttribText$

    If (TopLine + NumLines) > 22 Then
        TopLine = TopLine - ((TopLine + NumLines) - 22)
        Print String$(NumLines + 1, Chr$(10))
    End If

    If WipeScreen = True Then Cls

    If ForeColor > 0 Then COLOR ForeColor - 1
    IF BackColor > 0 THEN COLOR , BackColor - 1

    LOCATE TopLine, StartCol
    Print "╔"; String$(QuoteWidth + 2, "═"); "╗";

    For i = 1 To NumLines
        j = TopLine + i

        LOCATE j, StartCol
        Print "║"; String$(QuoteWidth + 2, " "); "║";

        Select Case Justification
        Case 1        'LEFT
            LOCATE j, StartCol + 2
        Case 2        'CENTERED
            LOCATE j, StartCol + 2 + Int((QuoteWidth - Len(QuoteText$(i))) / 2)
        Case 3        'RIGHT
            LOCATE j, StartCol + 2 + (QuoteWidth - Len(QuoteText$(i)))
        Case Else     'LEFT DEFAULT
            LOCATE j, StartCol + 2
        End Select
        Print QuoteText$(i);
    Next i

    LOCATE j + 1, StartCol
    Print "╚"; String$(QuoteWidth + 2, "═"); "╝";

    If j + 2 > CurrentLine Then CurrentLine = j + 2

    COLOR 7, 0
    Print ;

    LOCATE CurrentLine, 1

End Sub

Sub ShowGimme ()

    Print
    Print "       ┌──────────────────────────────────────────────────────────────┐         ";
    Print "       │ Dayquote 1.0  ─  Copyright 1994, 1995 by Freeware Unlimited. │         ";
    Print "       ├──────────────────────────────────────────────────────────────┤         ";
    Print "       │                                                              │         ";
    Print "       │  That's Right!  If you send me money, then I'll send 10% of  │         ";
    Print "       │  it directly back to you!!!  The more money you send to me,  │         ";
    Print "       │  the more money that will be sent to *YOU*...  Think of it!  │         ";
    Print "       │                                                              │         ";
    Print "       │  As a FREE bonus,  I'll also send you a catalog,  if I have  │         ";
    Print "       │  one finished, as well as MORE FREE SOFTWARE, if I have any  │         ";
    Print "       │  more programs done.  If you'll tell me what this program's  │         ";
    Print "       │  version number is, I'll ALSO send you a FREE UPGRADE,  if,  │         ";
    Print "       │  of course, there is one available.  Thank you, in advance.  │         ";
    Print "       │                                                              │         ";
    Print "       │                                                              │         ";
    Print "       │      ──────────────  FreeWare Unlimited  ──────────────      │         ";
    Print "       │                                                              │         ";
    Print "       │       12316 138th Street  ∞  Largo, Florida 34644-3016       │         ";
    Print "       │                                                              │         ";
    Print "       └──────────────────────────────────────────────────────────────┘         ";
    Print

    SYSTEM

End Sub

Sub ShowHelp ()

    Print
    Print "       ┌──────────────────────────────────────────────────────────────┐         ";
    Print "       │ DayQuote 1.0  ─  Copyright 1994, 1995 by Freeware Unlimited. │         ";
    Print "       ├──────────────────────────────────────────────────────────────┤         ";
    Print "       │ Usage: DAYQUOTE [switches] quotefil.ext                      │         ";
    Print "       │                                                              │         ";
    Print "       │  Switches:                                                   │         ";
    Print "       │   /?     - Shows this help screen.                           │         ";
    Print "       │   /F:c   - Use foreground color 'c', as listed below.        │         ";
    Print "       │   /B:c   - Use background color 'c', as listed below.        │         ";
    Print "       │   /L     - Left-justify the text.                            │         ";
    Print "       │   /R     - Right-justify the text.                           │         ";
    Print "       │   /C     - Center the text.                                  │         ";
    Print "       │   /S:#   - Start at specified column # (1-30). Default = 10  │         ";
    Print "       │   /E:#   - End at specified column # (50-80).  Default = 70  │         ";
    Print "       │   /T:#   - Top line # to begin on (1-24). Default = current  │         ";
    Print "       │   /W     - Wipe (clear) the screen before displaying.        │         ";
    Print "       │   /D[:n] - Create documentation file, DAYQUOTE.DOC, or 'n'.  │         ";
    Print "       │   /$     - Get money sent to you.                            │         ";
    Print "       │                                                              │         ";
    Print "       │    Available foreground colors and background colors are:    │         ";
    Print "       │                                                              │         ";
    Print "       │  BLACK, BLUE, GREEN, CYAN, RED, MAGENTA, BROWN, WHITE, GRAY  │         ";
    Print "       │  LTBLUE, LTGREEN, LTCYAN, LTRED, LTMAGENTA, YELLOW, BRWHITE  │         ";
    Print "       └──────────────────────────────────────────────────────────────┘         ";

    SYSTEM

End Sub

Sub ShowSyntax ()

    Print "Usage: DAYQUOTE [switches] quotefil.ext"
    Print
    Print "(Type 'DAYQUOTE /?' for help.)"
    SYSTEM

End Sub